Files
simply-tv/app/build.gradle.kts
T
2026-11-17 16:47:14 +01:00

69 lines
1.9 KiB
Kotlin
Raw Blame History

This file contains ambiguous Unicode characters
This file contains Unicode characters that might be confused with other characters. If you think that this is intentional, you can safely ignore this warning. Use the Escape button to reveal them.
import java.util.Properties
plugins {
id("com.android.application")
id("org.jetbrains.kotlin.android")
}
// Release signing: keystore/simply-tv.jks (created by scripts/build-apk.sh on the first build).
// Keep that file – Android only installs an update signed with the same key.
val signing = Properties().apply {
val f = rootProject.file("keystore/keystore.properties")
if (f.exists()) f.inputStream().use { load(it) }
}
android {
namespace = "io.simplydvb.tv"
compileSdk = 34
defaultConfig {
applicationId = "io.simplydvb.tv"
minSdk = 26
targetSdk = 34
versionCode = 9
versionName = "0.8.0"
}
signingConfigs {
create("release") {
if (signing.isNotEmpty()) {
storeFile = rootProject.file(signing.getProperty("storeFile"))
storePassword = signing.getProperty("storePassword")
keyAlias = signing.getProperty("keyAlias")
keyPassword = signing.getProperty("keyPassword")
}
}
}
buildTypes {
release {
isMinifyEnabled = false
signingConfig = if (signing.isNotEmpty()) signingConfigs.getByName("release") else signingConfigs.getByName("debug")
}
}
compileOptions {
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
}
kotlinOptions {
jvmTarget = "17"
}
testOptions {
unitTests.isReturnDefaultValues = true
}
lint {
abortOnError = false
checkReleaseBuilds = false
}
}
dependencies {
val media3 = "1.4.1"
implementation("androidx.media3:media3-exoplayer:$media3")
implementation("androidx.media3:media3-ui:$media3")
implementation("androidx.work:work-runtime:2.9.1")
implementation("com.google.zxing:core:3.5.3")
testImplementation("junit:junit:4.13.2")
}